Merge git://git.samba.org/jelmer/ikiwiki

IkiWiki/Rcs/bazaar.pm

@@ -0,0 +1,163 @@
+#!/usr/bin/perl
+
+use warnings;
+use strict;
+use IkiWiki;
+use Encode;
+use open qw{:utf8 :std};
+
+package IkiWiki;
+
+sub bazaar_log($) {
+	my $out = shift;
+	my @infos = ();
+	my $key = undef;
+
+	while (<$out>) {
+		my $line = $_;
+		my ($value);
+		if ($line =~ /^message:/) {
+			$key = "message";
+			$infos[$#infos]{$key} = "";
+		} elsif ($line =~ /^(modified|added|renamed|renamed and modified|removed):/) {
+			$key = "files";
+			unless (defined($infos[$#infos]{$key})) { $infos[$#infos]{$key} = ""; }
+		} elsif (defined($key) and $line =~ /^  (.*)/) {
+			$infos[$#infos]{$key} .= $1;
+		} elsif ($line eq "------------------------------------------------------------\n") {
+			$key = undef;
+			push (@infos, {});
+		} else {
+			chomp $line;
+				($key, $value) = split /: +/, $line, 2;
+			$infos[$#infos]{$key} = $value;
+		} 
+	}
+	close $out;
+
+	return @infos;
+}
+
+sub rcs_update () { #{{{
+	my @cmdline = ("bzr", "$config{srcdir}", "update");
+	if (system(@cmdline) != 0) {
+		warn "'@cmdline' failed: $!";
+	}
+} #}}}
+
+sub rcs_prepedit ($) { #{{{
+	return "";
+} #}}}
+
+sub rcs_commit ($$$;$$) { #{{{
+	my ($file, $message, $rcstoken, $user, $ipaddr) = @_;
+
+	if (defined $user) {
+		$user = possibly_foolish_untaint($user);
+	}
+	elsif (defined $ipaddr) {
+		$user = "Anonymous from ".possibly_foolish_untaint($ipaddr);
+	}
+	else {
+		$user = "Anonymous";
+	}
+
+	$message = possibly_foolish_untaint($message);
+	if (! length $message) {
+		$message = "no message given";
+	}
+
+	my @cmdline = ("bzr", "commit", 
+	               "-m", $message, "--author", $user, $config{srcdir});
+	if (system(@cmdline) != 0) {
+		warn "'@cmdline' failed: $!";
+	}
+
+	return undef; # success
+} #}}}
+
+sub rcs_add ($) { # {{{
+	my ($file) = @_;
+
+	my @cmdline = ("bzr", "add", "$config{srcdir}/$file");
+	if (system(@cmdline) != 0) {
+		warn "'@cmdline' failed: $!";
+	}
+} #}}}
+
+sub rcs_recentchanges ($) { #{{{
+	my ($num) = @_;
+
+	eval q{use CGI 'escapeHTML'};
+	error($@) if $@;
+
+	my @cmdline = ("bzr", "log", "-v", "--limit", $num, $config{srcdir});
+	open (my $out, "@cmdline |");
+
+	eval q{use Date::Parse};
+	error($@) if $@;
+
+	my @ret;
+	foreach my $info (bazaar_log($out)) {
+		my @pages = ();
+		my @message = ();
+        
+		foreach my $msgline (split(/\n/, $info->{message})) {
+			push @message, { line => $msgline };
+		}
+
+		foreach my $file (split(/\n/, $info->{files})) {
+			my $diffurl = $config{'diffurl'};
+			$diffurl =~ s/\[\[file\]\]/$file/go;
+			$diffurl =~ s/\[\[r2\]\]/$info->{revno}/go;
+
+			push @pages, {
+				page => pagename($file),
+				diffurl => $diffurl,
+			};
+		}
+
+		my $user = $info->{"committer"};
+		if (defined($info->{"author"})) { $user = $info->{"author"}; }
+		$user =~ s/\s*<.*>\s*$//;
+		$user =~ s/^\s*//;
+
+		push @ret, {
+			rev        => $info->{"revno"},
+			user       => $user,
+			committype => "bazaar",
+			when       => time - str2time($info->{"timestamp"}),
+			message    => [@message],
+			pages      => [@pages],
+		};
+	}
+
+	return @ret;
+} #}}}
+
+sub rcs_notify () { #{{{
+	# TODO
+} #}}}
+
+sub rcs_getctime ($) { #{{{
+	my ($file) = @_;
+
+	# XXX filename passes through the shell here, should try to avoid
+	# that just in case
+	my @cmdline = ("bzr", "log", "--limit", '1', "$config{srcdir}/$file");
+	open (my $out, "@cmdline |");
+
+	my @log = bazaar_log($out);
+
+	if (length @log < 1) {
+		return 0;
+	}
+
+	eval q{use Date::Parse};
+	error($@) if $@;
+	
+	my $ctime = str2time($log[0]->{"timestamp"});
+	return $ctime;
+} #}}}
+
+1

debian/control

@@ -13,7 +13,7 @@ Vcs-Browser: http://git.ikiwiki.info/?p=ikiwiki
 Package: ikiwiki
 Architecture: all
 Depends: ${perl:Depends}, markdown, libhtml-template-perl, libhtml-parser-perl, liburi-perl
-Recommends: gcc | c-compiler, libc6-dev | libc-dev, subversion | git-core | tla | mercurial, libxml-simple-perl, libnet-openid-consumer-perl, liblwpx-paranoidagent-perl, libtimedate-perl, libhtml-scrubber-perl, libcgi-formbuilder-perl (>= 3.05), libtime-duration-perl, libcgi-session-perl (>= 4.14-1), libmail-sendmail-perl
+Recommends: gcc | c-compiler, libc6-dev | libc-dev, subversion | git-core | tla | bzr | mercurial, libxml-simple-perl, libnet-openid-consumer-perl, liblwpx-paranoidagent-perl, libtimedate-perl, libhtml-scrubber-perl, libcgi-formbuilder-perl (>= 3.05), libtime-duration-perl, libcgi-session-perl (>= 4.14-1), libmail-sendmail-perl
 Suggests: viewvc | gitweb | viewcvs, hyperestraier, librpc-xml-perl, libtext-wikiformat-perl, python, python-docutils, polygen, tidy, libxml-feed-perl, libmailtools-perl, perlmagick, libfile-mimeinfo-perl, libcrypt-ssleay-perl, liblocale-gettext-perl (>= 1.05-1), libtext-typography-perl, libtext-csv-perl, libdigest-sha1-perl, graphviz
 Conflicts: ikiwiki-plugin-table
 Replaces: ikiwiki-plugin-table

t/bazaar.t

@@ -0,0 +1,62 @@
+#!/usr/bin/perl
+use warnings;
+use strict;
+my $dir;
+BEGIN {
+	$dir = "/tmp/ikiwiki-test-bzr.$$";
+	my $bzr=`which bzr`;
+	chomp $bzr;
+	if (! -x $bzr || ! mkdir($dir)) {
+		eval q{
+			use Test::More skip_all => "bzr not available or could not make test dir"
+		}
+	}
+}
+use Test::More tests => 11;
+
+BEGIN { use_ok("IkiWiki"); }
+
+%config=IkiWiki::defaultconfig();
+$config{rcs} = "bazaar";
+$config{srcdir} = "$dir/repo";
+IkiWiki::checkconfig();
+
+system "bzr init $config{srcdir}";
+
+# Web commit
+my $test1 = readfile("t/test1.mdwn");
+writefile('test1.mdwn', $config{srcdir}, $test1);
+IkiWiki::rcs_add("test1.mdwn");
+IkiWiki::rcs_commit("test1.mdwn", "Added the first page", "moo", "Joe User");
+
+my @changes;
+@changes = IkiWiki::rcs_recentchanges(3);
+
+is($#changes, 0);
+is($changes[0]{message}[0]{"line"}, "Added the first page");
+is($changes[0]{pages}[0]{"page"}, "test1.mdwn");
+is($changes[0]{user}, "Joe User");
+	
+# Manual commit
+my $username = "Foo Bar";
+my $user = "$username <foo.bar\@example.com>";
+my $message = "Added the second page";
+
+my $test2 = readfile("t/test2.mdwn");
+writefile('test2.mdwn', $config{srcdir}, $test2);
+system "bzr add $config{srcdir}/test2.mdwn";
+system "bzr commit --author \"$user\" -m \"$message\" $config{srcdir}";
+	
+@changes = IkiWiki::rcs_recentchanges(3);
+
+is($#changes, 1);
+is($changes[0]{message}[0]{"line"}, $message);
+is($changes[0]{user}, $username);
+is($changes[0]{pages}[0]{"page"}, "test2.mdwn");
+
+is($changes[1]{pages}[0]{"page"}, "test1.mdwn");
+
+my $ctime = IkiWiki::rcs_getctime("test2.mdwn");
+ok($ctime >= time() - 20);
+
+system "rm -rf $dir";