#!/usr/bin/gnuplot

set datafile separator ','
set terminal epslatex size 9cm,5cm font ',10pt' color colortext 
set output 'modulator.tex'

set border linewidth 2
set style line 1 linecolor rgb '#0060ad' linetype 1 linewidth 5
set style line 2 linecolor rgb '#dd181f' linetype 1 linewidth 5

set style rect fc lt -1 fs solid 0.15 noborder
set obj rect from 27.5, graph 0 to 28.5, graph 1

set xlabel 'Modulation voltage (V)'
set ylabel 'Insersion loss (dB)' textcolor linestyle 1
set y2label 'Phase shift (\degree)' textcolor linestyle 2
set format y '%.1f'
set xtics nomirror
set ytics 0.5 nomirror textcolor linestyle 1
set y2tics textcolor linestyle 2

unset key


plot 'modulator.csv' u 1:2 w lines linestyle 1,\
	'modulator.csv' u 1:3 w lines axes x1y2 linestyle 2
